Microsoft Windows 10

Windows 10 Pro non si attiva con il Product Key nel bios

In alcuni casi è possibile che Windows 10 Pro integrato nel sistema non si attiva. Il problema può verificarsi nei portatili, ma anche in alcuni desktop dei brand più famosi, in cui la licenza e quindi il Product Key di Windows 10 è stata inserita direttamente nel bios. Quindi non esiste nessuna etichetta con il Product Key, come eravamo abituati a trovare nelle versioni precedenti di Windows fino a Windows 7. Infatti l’integrazione del Product Key nel firmware è stata adottata già da Windows 8.

Ne deriva che al momento dell’installazione di Windows non devi più scegliere quale versione installare (Home, Pro ecc.) ma ti viene acquisita direttamente dal programma d’installazione attraverso il Product Key impresso nel bios.

Come ho detto può accadere che Windows 10 Pro non si voglia attivare in uno di questi computer con il Product Key integrato.

Allora andiamo a vedere come risolvere questo problema di Windows 10 Pro che non si attiva prima, eventualmente, di contattare la Microsoft.

  1. Apri una finestra del Prompt dei comandi con poteri amministrativi
  2. Digita il seguente comando che serve per rilevare il Product Key:

wmic path SoftwareLicensingService get OA3xOriginalProductKey

Nel caso che il Product Key non venga rilevato bisogna utilizzare uno script: clicca qui per andare al codice dello script

  1. Successivamente devi aggiornare il Product Key del sistema operativo con il comando:

slmgr /ipk XXXXX-XXXXX-XXXXX-XXXXX-XXXXX

Dove ovviamente devi sostituire le X con il Product Key rivelato inserendo anche i trattini –

  1. Ora devi forzare l’attivazione con questo comando:

slmgr /ato

Script per rivelare il Product Key integrato ne bios

Per utilizzare questo script devi creare un file di testo, va bene anche il classico Notepad, poi incolla il seguente testo dopo averlo copiato. Ma devi poi cambiare l’estensione in .vbs

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell") 
'Set registry key path 
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\" 
'Registry key value 
DigitalID = objshell.RegRead(Path & "DigitalProductId") 
Dim ProductName,ProductID,ProductKey,ProductData 
'Get ProductName, ProductID, ProductKey 
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName") 
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID") 
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey 
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then 
   Save ProductData  
End If 
 
 
 
'Convert binary to chars 
Function ConvertToKey(Key) 
    Const KeyOffset = 52 
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert 
    'Check if OS is Windows 8 
    isWin8 = (Key(66) \ 6) And 1 
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) 
    i = 24 
    Maps = "BCDFGHJKMPQRTVWXY2346789" 
    Do 
           Current= 0 
        j = 14 
        Do 
           Current = Current* 256 
           Current = Key(j + KeyOffset) + Current 
           Key(j + KeyOffset) = (Current \ 24) 
           Current=Current Mod 24 
            j = j -1 
        Loop While j >= 0 
        i = i -1 
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput 
        Last = Current 
    Loop While i >= 0  
     
    If (isWin8 = 1) Then 
        keypart1 = Mid(KeyOutput, 2, Last) 
        insert = "N" 
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0) 
        If Last = 0 Then KeyOutput = insert & KeyOutput 
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5) 
    
     
End Function 
'Save data to a file 
Function Save(Data) 
    Dim fso, fName, txt,objshell,UserName 
    Set objshell = CreateObject("wscript.shell") 
    'Get current user name  
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
    'Create a text file on desktop  
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt" 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set txt = fso.CreateTextFile(fName) 
    txt.Writeline Data 
    txt.Close 
End Function 

Ora non ti rimane che cliccare due volte sul file appena creato a cui ha dato l’estensione .vbs e ti comparirà il Product Key di Windows 10. Se preferisci puoi scaricare il file cliccando qui sopra.

close

ISCRIVITI ALLA NEWS LETTER
NON COSTA NIENTE!!!

Potrai essere aggiornato ogni volta che esce un articolo.
È gratis, interessante e non invasiva.
I TUOI DATI NON VERRANNO MAI CEDUTI A NESSUNO E PER NESSUNA RAGIONE.

Non inviamo spam! Leggi la nostra Informativa sulla privacy per avere maggiori informazioni.

Ciao e Benvenuto nel Blog di Fabio Bernini

%d blogger hanno fatto clic su Mi Piace per questo: